10  REM
20  REM
30  REM                EXPERIMENT 11. PARTIAL MOLAL VOLUME
40  REM
50  REM                         (LAB.5.WBASIC)
60  REM
70  REM
80  REM
90  REM
92 DIM M(10), EM(10), D(10), W(10), B(10), ED(10), MO(10), C(10), EC(10)
93 DIM F(10), EF(10), P(10), G(10), EG(10), I(10), EI(10), EMO(10)
94 DIM J(10), EJ(10), EP(10), Z(10), MS(10), EMS(10), X(10), V1(10)
95 DIM L(10), EL(10), V1O(10), EV1O(10), SV1(10), V2(10), MP(10), EMP(10)
96 DIM SV2(10), MI(10)
100 OPEN "A:\INPUT5" FOR INPUT AS #3
110 OPEN "A:\OUTPUT" FOR OUTPUT AS #2
120 ON EOF(3) GOTO 2910
130  REMd
140  REM                        "INPUT YOUR NAME"
150 INPUT #3, E$
160  REM                 "INPUT THE NAME OF THE EXPERIMENT "
170 INPUT #3, A$
180  REM                   "INPUT THE NAME OF YOUR PARTNER "
190 INPUT #3, B$
200  REM                        "INPUT THE DATE "
210 LINE INPUT #3, C$
220 PRINT #2, "NAME: ", E$
230 PRINT #2, " "
240 PRINT #2, "EXPERIMENT: ", A$
250 PRINT #2, " "
260 PRINT #2, "DATE: ", C$
270 PRINT #2, " "
280 PRINT #2, "PARTNER: ", B$
290 PRINT #2, " "
300 FOR I = 1 TO 5
310 PRINT #2, " "
320 NEXT I
330 INPUT #3, WE, EWE
340 PRINT #2, "THE WEIGHT OF THE EMPTY PYCNOMETER"
350 PRINT #2, "     ="; WE; "+/-"; EWE; "grams"
360 PRINT #2, " "
370 INPUT #3, WO, EWO
380 PRINT #2, "THE WEIGHT OF THE PYCNOMETER FILLED WITH H20"
390 PRINT #2, "     ="; WO; "+/-"; EWO; "grams"
400 PRINT #2, " "
410 INPUT #3, T
420 PRINT #2, "THE TEMPERATURE OF THE BATH"
430 PRINT #2, "     ="; T; "degC"
440 PRINT #2, " "
450 INPUT #3, D0, ED0
460 PRINT #2, "THE DENSITY OF WATER AT"; T; "degC"
470 PRINT #2, "     ="; D0; "+/-"; ED0; "grams"
480 PRINT #2, " "
490 INPUT #3, M(1), EM(1)
500 PRINT #2, "THE INITIAL CONCENTRATION OF NACL (MOLARITY)"
510 PRINT #2, "     ="; M(1); "+/-"; EM(1); "mol/dm3"
520 RUM = EM(1) / M(1)
530 REM    = RELATIVE ERROR IN NACL MOLARITY
540 REM
550 PRINT #2, " "
560 INPUT #3, N
570 PRINT #2, N; "CONCENTRATIONS WERE RUN."
580 PRINT #2, " "
590 PRINT #2, " "
600 VP = (WO - WE) / D0: REM                           VP = VOLUME OF PYCNOMETER
610 A = WO - WE
620 EA = (EWO ^ 2 + EWE ^ 2) ^ .5
630 EVP = VP * ((EA / A) ^ 2 + (ED0 / D0) ^ 2) ^ .5
640 REM      ERROR IN THE VOLUME OF THE PYCNOMETER
650 REM
660 PRINT #2, " "
670 INPUT #3, EWP
680 PRINT #2, "THE UNCERTAINTY IN THE WEIGHT OF THE PYCNOMETER FILLED"
690 PRINT #2, "WITH THE VARIOUS NACL SOLUTIONS = +/-"; EWP; "grams"
700 PRINT #2, " "
710 FOR I = 2 TO N
720 M(I) = M(I - 1) / 2: REM                                         (MOLARITIES)
730 EM(I) = RUM * M(I)
740 NEXT I
750 FOR I = 1 TO N
760 PRINT #2, "RUN NO."; I
770 PRINT #2, "THE CONCENTRATION (MOLARITY) FOR #"; I
780 PRINT #2, "     ="; M(I); "+/-"; EM(I); "mol/dm3"
790 PRINT #2, " "
800 INPUT #3, W(I)
810 PRINT #2, "THE WEIGHT OF THE FILLED PYCNOMETER"
820 PRINT #2, "     ="; W(I); "grams"
830 PRINT #2, " "
840 PRINT #2, " "
850 NEXT I
860 FOR I = 1 TO N
870 REM D(I)=(W(I)-WE)/VP
880 REM     = DENSITIES
890 REM
900 B(I) = W(I) - WE
910 EB = (EWP ^ 2 + EWE ^ 2) ^ .5
920 D(I) = B(I) / VP
930 ED(I) = D(I) * ((EB / B(I)) ^ 2 + (EVP / VP) ^ 2) ^ .5
940 REM      = ERROR IN THE DENSITY OF THE NACL SOLUTIONS
950 REM
960 REM MO(I)=1/((D(I)/M(I))-(58.45/1000))
970 REM      = MOLALITIES
980 REM
990 C(I) = D(I) / M(I)
1000 EC(I) = C(I) * ((ED / D(I)) ^ 2 + (EM(I) / M(I)) ^ 2) ^ .5
1010 F(I) = C(I) - 58.45 / 1000
1020 EF(I) = EC(I)
1030 MO(I) = 1 / F(I)
1040 EMO(I) = MO(I) * EF(I) / F(I)
1050 REM       = ERROR IN THE MOLALITIES OF THE NACL SOLUTIONS
1060 REM
1070 REM P(I)=(1/D(I))*(58.45-(1000/MO(I))*(W(I)-WO)/(WO-WE))
1080 REM     = PHI
1090 REM
1100 G(I) = W(I) - WO
1110 EG(I) = (EW(I) ^ 2 + EWO ^ 2) ^ .5
1120 H = WO - WE
1130 EH = (EWO ^ 2 + EWE ^ 2) ^ .5
1140 I(I) = 1000 * G(I) / (MO(I) * H)
1150 EI(I) = I(I) * ((EG(I) / G(I)) ^ 2 + (EMO(I) / MO(I)) ^ 2 + (EH / H) ^ 2) ^ .5
1160 J(I) = 58.45 - I(I)
1170 EJ(I) = EI(I)
1180 P(I) = J(I) / D(I)
1190 EP(I) = P(I) * ((EJ(I) / J(I)) ^ 2 + (ED(I) / D(I)) ^ 2) ^ .5
1200 REM      = ERROR IN PHI
1210 REM
1220 REM  I(I)=(1000/MO(I))*(W(I)-WO)/(WO-WE)        (1000/M)(W-WO)/(WO-WE)
1230 REM      = FUNCTION (TO BE PLOTTED)
1240 REM
1250 REM  EI(I)= ERROR IN THIS FUNCTION TO BE PLOTTED
1260 REM
1270 NEXT I
1280 FOR P = 1 TO N
1290 Z(P) = MO(P) ^ .5: REM                    Z(P) = SQUARE ROOT OF MOLALITY
1300 MS(P) = Z(P)
1310 EMS(P) = .5 * Z(P) * EMO(P) / MO(P)
1320 REM       = ERROR IN THE SQUARE ROOT OF MOLALITY
1330 REM
1340 NEXT P
1350 SUMX = 0!
1360 SUMY = 0!
1370 SUMY2 = 0!
1380 SUMX2 = 0!
1390 SUMXY = 0!
1400 FOR II = 1 TO N
1410 SUMX = SUMX + Z(II)
1420 SUMY = SUMY + P(II)
1430 SUMY2 = SUMY2 + P(II) ^ 2
1440 SUMX2 = SUMX2 + Z(II) ^ 2
1450 SUMXY = SUMXY + P(II) * Z(II)
1460 NEXT II
1470 XMEAN = SUMX / N
1480 YMEAN = SUMY / N
1490 YINT = (SUMX2 * SUMY - SUMX * SUMXY) / (N * SUMX2 - SUMX ^ 2): REM        Y-INT=PHI(O)
1500 SLOPE = (SUMY - N * YINT) / SUMX: REM                                     SLOPE
1510 QQ = N * SUMXY - SUMX * SUMY
1520 PP = ((N * SUMX2 - (SUMX ^ 2)) * (N * SUMY2 - (SUMY ^ 2))) ^ .5
1530 r = QQ / PP: REM                              (CORRELATION COEFFICIENT)
1540 r2 = (r ^ 2) * 100: REM                                  (PERCENT OF FIT)
1550 SNI = 0!
1560 SIGMA = 0!
1570 FOR K = 1 TO N
1580 YCALC = SLOPE * Z(K) + YINT
1590 SNI = ABS(YCALC - P(K))
1600 SIGMA = SIGMA + SNI ^ 2
1610 NEXT K
1620 SY = (SIGMA / (N - 2)) ^ .5: REM                               SY = ERROR IN Y
1630 SM = ((N / (N * SUMX2 - SUMX ^ 2)) ^ .5) * SY: REM           SM = ERROR IN SLOPE
1640 SB = ((SUMX2 / (N * SUMX2 - SUMX ^ 2)) ^ .5) * SY: REM          SB = ERROR IN Y-INT
1650 X(1) = 0!: REM                                           X(I) = MOLALITY
1660 FOR I = 1 TO 6
1670  REM   V1(I)=(18.016/D0)-((X(I)/55.51)*(X(I)^0.5)*(SLOPE/2))
1680  REM        = PARTIAL MOLAR VOLUME OF V1
1690  REM
1700 L(I) = X(I) ^ 1.5 * SLOPE / (55.506 * 2)
1710 EL(I) = X(I) ^ 1.5 * SM / (55.506 * 2)
1720 V1O = 18.016 / .997
1730 EV1O = V1O * ((.001 / 18.016) ^ 2 + (.0001 / .997) ^ 2) ^ .5
1740 V1(I) = V1O - L(I)
1750 SV1(I) = (EV1O ^ 2 + EL(I) ^ 2) ^ .5
1760  REM      = ERROR IN PARTIAL MOLAR VOLUME OF V1
1770  REM
1780  REM    V2(I) = YINT + 1.5*SLOPE*X(I)^0.5
1790  REM          = PARTIAL MOLAR VOLUME OF V2
1800  REM
1810 MP(I) = 1.5 * SLOPE * X(I) ^ .5
1820 EMP(I) = 1.5 * SM * X(I) ^ .5
1830 V2(I) = YINT + MP(I)
1840 SV2(I) = (SB ^ 2 + EMP(I) ^ 2) ^ .5
1850  REM      = ERROR IN PARTIAL MOLAR VOLUME OF V2
1860  REM
1870 X(I + 1) = X(I) + .5
1880 NEXT I
1890  REM
1900 PRINT #2, " "
1910 FOR I = 1 TO 10
1920 PRINT " "
1930 NEXT I
1940 PRINT #2, " ", "PLOT OF PHI VS. SQUARE ROOT OF MOLALITY"
1950 PRINT #2, " ", "===========     ======================="
1960 PRINT #2, " "
1970 PRINT #2, " "
1980 PRINT #2, "PHI", " ", "SQUARE ROOT OF MOLALITY"
1990 PRINT #2, "=======================", "======================="
2000 PRINT #2, " "
2010 FOR I = 1 TO N
2020 PRINT #2, P(I), "+/-"; EP(I), MS(I), "+/-"; EMS(I)
2030 NEXT I
2040 PRINT #2, " "
2050 PRINT #2, " ", "SLOPE"
2060 PRINT #2, " ", "======================"
2070 PRINT #2, " ", "   ="; SLOPE; "+/-"; SM
2080 PRINT #2, " "
2090 PRINT #2, " ", "PHI (O)"
2100 PRINT #2, " ", "=========================="
2110 PRINT #2, " ", "   ="; YINT; "+/-"; SB
2120 PRINT #2, " "
2130 PRINT #2, " ", "CORRELATION COEFFICIENT"
2140 PRINT #2, " ", "======================="
2150 PRINT #2, " ", "   = "; r
2160 PRINT #2, " "
2170 PRINT #2, " ", "PERCENT OF FIT"
2180 PRINT #2, " ", "=============="
2190 PRINT #2, " ", "   = "; r2; "%"
2200 FOR I = 1 TO 3
2210 PRINT #2, " "
2220 NEXT I
2230 PRINT #2, " ", "PLOT OF V2 VS. MOLALITY"
2240 PRINT #2, " ", "==========     ========"
2250 PRINT #2, " "
2260 PRINT #2, "  V2", " ", "MOLALITY"
2270 PRINT #2, "======================", "======================="
2280 FOR I = 1 TO 6
2290 PRINT #2, V2(I), "+/-"; SV2(I), X(I)
2300 NEXT I
2310 FOR I = 1 TO 3
2320 PRINT #2, " "
2330 NEXT I
2340 PRINT #2, " ", "PLOT OF V1 VS. MOLALITY"
2350 PRINT #2, " ", "==========     ========"
2360 PRINT #2, " "
2370 PRINT #2, "  V1", " ", "MOLALITY"
2380 PRINT #2, "======================", "======================="
2390 PRINT #2, " "
2400 FOR I = 1 TO 6
2410 PRINT #2, V1(I), "+/-"; SV1(I), X(I)
2420 NEXT I
2430 FOR I = 1 TO 3
2440 PRINT #2, " "
2450 NEXT I
2460 PRINT #2, " ", "RUN NO.", "DENSITY"
2470 PRINT #2, " ", "=======", "======================="
2480 FOR I = 1 TO N
2490 PRINT #2, " ", I, D(I), "+/-"; ED(I)
2500 NEXT I
2510 PRINT #2, " "
2520 PRINT #2, " "
2530 PRINT #2, " ", "RUN NO.", "MOLARITY"
2540 PRINT #2, " ", "=======", "======================="
2550 FOR I = 1 TO N
2560 PRINT #2, " ", I, M(I), "+/-"; EM(I)
2570 NEXT I
2580 PRINT #2, " "
2590 PRINT #2, " "
2600 PRINT #2, " ", "RUN NO.", "MOLALITY"
2610 PRINT #2, " ", "=======", "======================="
2620 FOR I = 1 TO N
2630 PRINT #2, " ", I, MO(I), "+/-"; EMO(I)
2640 NEXT I
2650 PRINT #2, " "
2660 PRINT #2, " "
2670 PRINT #2, " ", "RUN NO.", "PHI"
2680 PRINT #2, " ", "=======", "======================="
2690 FOR I = 1 TO N
2700 PRINT #2, " ", I, P(I), "+/-"; EP(I)
2710 NEXT I
2720 PRINT #2, " "
2730 PRINT #2, " "
2740 PRINT #2, " ", "RUN NO.", "(1000/M)(W-WO)/(WO-WE)"
2750 PRINT #2, " ", "=======", "======================"
2760 FOR I = 1 TO N
2770 PRINT #2, " ", I, I(I), "+/-"; EI(I)
2780 NEXT I
2790 PRINT #2, " "
2800 PRINT #2, " "
2810 PRINT #2, "VOLUME OF PYCNOMETER ="; VP; "+/-"; EVP; "CM3"
2820 PRINT #2, "====== == ==========   "
2830 PRINT #2, " "
2840 PRINT #2, " "
2850 PRINT #2, "PHI (O) ="; YINT; "+/-"; SB; "CM3"
2860 PRINT #2, "======="
2870 PRINT #2, " "
2880 PRINT #2, " "
2890 PRINT #2, "DPHI/DM(1/2) ="; SLOPE; "+/-"; SM; "CM3/MOLALITY(1/2)"
2900 PRINT #2, "============   "
2910 CLOSE #2
2920 CLOSE #3
2930 END